Director: file PDF nel MIAW

Premetto di non sapere se ciò che chiedi sia realmente fattibile, ma non mi risulta che lo sia, soprattutto con la versione base di Director. Tuttavia, aprendo il tuo File PDF da Acrobat hai delle soluzioni alternative:
• salvare il PDF in RTF (te lo consiglio nel caso che il PDF sia di solo testo);
• salvare il PDF in JPG o PNG (ti crea automaticamente un file per ogni pagina del pdf, pulito e preciso);
• salvare il PDF in altri formati, a seconda delle esigenze.
Così invece di importare un PDF in Director (che in Director naturalmente non è ammesso), importerai un file per ogni pagina del PDF. Buon lavoro, ciao.

Ho letto da qualche parte che utilizzando l'Adobe Acrobat Control activex la cosa sia possibile. sto provando ma non mi riesce difar vedere il file all'interno della finestra activex che si crea con l'Adobe Acrobat Control activex.
Ne sai niente?

Mai provato, sorry...
Aspettiamo altre risposte dalla comunità, nel frattempo io risolverei come descritto sopra. Ciao.

...Ritornando sull'argomento: Adobe Acrobat Control activex
posto uno script (non è mio) che ho trovato "ravanando" nei vari forum in giro per la rete. Solo dopo ho scoperto che l'autore è anche un adepto al "nostro" forum (Paolibo).
Comunque sia lo script funziona egregiamente, l'ho provato e mi ha risolto non pochi problemi con i file pdf multipagina; anche se solo su piattaforma PC (a detta di Paolibo), ma tanto mi basta.
property sourceFile, spriteNum, toolBar, scrollBar, buttonDo, xSprite
on getPropertyDescriptionList me
p_list = [:]
if (sprite the currentSpriteNum).member.type = #activeX then
addProp p_list, #sourceFile, [#default : "file.pdf", #comment : "Pdf iniziale: the moviePath &", #format: #string]
addProp p_list, #toolBar, [#format : #boolean, #default : False, #comment : "Mostra Tool bar?"]
addProp p_list, #scrollBar, [#format : #boolean, #default : False, #comment : "Mostra Scroll bar?"]
else
addProp p_list, #buttonDo, [#format : #symbol, #default : #NextPage, #comment : "Bottoni da settare:" , #range : [#NextPage, #PreviousPage, #FirstPage, #LastPage, #Print]]
end if
return p_list
end
on beginSprite me
if (sprite spriteNum).member.type = #activeX then
(sprite spriteNum).src = the moviePath & sourceFile
setShowScrollbars(sprite spriteNum, scrollBar)
setShowToolbar(sprite spriteNum, toolBar)
sendAllSprites(#iAmX, spriteNum)
end if
end
on iAmX me, whatSprite
xSprite = whatSprite
end
on mouseUp me
if (sprite spriteNum).member.type <> #activeX then
case buttonDo of
#NextPage : goToNextPage(sprite xSprite)
#PreviousPage :goToPreviousPage(sprite xSprite)
#FirstPage : goToFirstPage(sprite xSprite)
#LastPage : goToLastPage(sprite xSprite)
#Print : print(sprite xSprite)
end case
end if
end
Aggiungo anche delle notazioni dell'autore che ho trovato interessanti per far funzionare lo script in modo idoneo.
1. Metti l'activex nel secondo frame
2. associa il behavior
3. setta i valori dello stesso in base alle tue esigenze cliccando sull'icona Parameters del property inspector
ovviamente il tuo pdf dovrà stare allo stesso livello del proiettore.
- IL SUDDETTO SCRIPT E LA SUDDETTA PROCEDURA SONO STATI GENTILMENTE CONCESSI DALL'AUTORE -
Ciao a tutti.